Method: (WRITE-CODE-DESCRIPTOR DEFCLASS-DESCRIPTOR T HTML-GENERATOR)

Source

(defmethod write-code-descriptor ((descriptor defclass-descriptor) part (generator html-generator))
  (declare (ignore part))
  (when (slots descriptor)
    (<:h2 "Slots")
    (<:ul :class "slots"
     (dolist (slot (slots descriptor))
       (<:li (<:em (<:as-html (name slot)))
	     (when (slot-type slot)
	       (<:as-html " ")
	       (<:span :class "slot-type" (<:as-html (princ-to-string (slot-type slot)))))
             (when (docstring slot)
               (<:p :class "slot-description"
		    (<:as-html (docstring slot))))))))
  (<:h2 "Hierachy")
  (<:h3 "Precedence List")
  (flet ((make-class-link (class)
           (aif (find-descriptor "class" (class-name class))
                (<:a :href (strcat "../" (make-anchor-link it))
                     (<:as-html (class-name class)))
                (<:as-html (class-name class)))))
    (<:ul
     (dolist (class (mopp:class-direct-superclasses (find-class (name descriptor))))
       (<:li (make-class-link class))))
    (awhen (mopp:class-direct-subclasses (find-class (name descriptor)))
      (<:h3 "Sub Classes")
      (<:ul
       (dolist (sub it)
         (<:li (make-class-link sub)))))))